PROCEDURE Convert_DSK
(* Sector 0 has to be done LAST, or OS-9 will get confused about the disk
(* parameters
(* Or, later, we can change it to use the PD.OPT flag for 'non-os9 disk'
(* Have to make sure that that works with stock OS9, though...may be CC3Disk
(* Edition #11 or higher only
DIM in,out:BYTE
DIM c:INTEGER
DIM nm$,out$:STRING[80]
DIM sector(256):BYTE
DIM track(4608):BYTE
PRINT "NOTE: This program REQUIRES the DMODE command to be handy"
PRINT "It is also hard-coded for 35 track, single sided, double density disks"
PRINT "If you need to do a 40 track disk, edit this source code, and change the"
PRINT "DMODE command to say 'cyl=28', and change the 'FOR c=1 TO 34' to 'FOR c=1 TO"
PRINT "39'"
INPUT "Name of .DSK file to Put onto floppy:",nm$
OPEN #in,nm$:READ
INPUT "Name of drive to write it out to (MAKE SURE IT IS A FLOPPY!!):" ,out$
SHELL "dmode "+out$+" cyl=23 sid=1 sct=12 t0s=12 ilv=3"
OPEN #out,out$+"@":WRITE
SEEK #out,0
FOR c=1 TO 17
  PRINT "Copying sector ";c
  SEEK #in,c*256.
  GET #in,sector
  SEEK #out,256.*c
  PUT #out,sector
NEXT c
FOR c=1 TO 34
  PRINT "Copying track ";c
  SEEK #in,c*4608.
  GET #in,track
  SEEK #out,c*4608.
  PUT #out,track
NEXT c
PRINT "Copying Sector 0"
SEEK #in,0
SEEK #out,0
GET #in,sector
PUT #out,sector
CLOSE #out
CLOSE #in